13 « August « 2011

Harmonic vibration of a damped system

Posted in Engineering by Yi Zhang on 08/13/2011

Unlike in previous post that phase change could only be $0$ or $\pi$ , in the damped system, as the ratio between dynamics response and static response is expressed in the same way as the undamped case
$\frac{u_d}{u_{s0}}=R_d\sin(\omega t-\phi),$
the phase lag $\phi$ varies in $[0,\pi]$ . The following Mathematica outputs the displacement response factor, phase lag and normalized time history as the function of damping ratio $\zeta$ and frequency ratio $w=\omega/\omega_0$ .

Rd[w_, \[Zeta]_] := 1/Sqrt[(1 - w^2)^2 + (2 \[Zeta] w)^2]
\[Phi][w_, \[Zeta]_] := -ArcTan[1 - w^2, -2 \[Zeta] w]
ud[w_, \[Zeta]_, t_] :=
 Rd[w, \[Zeta]] Sin[2 Pi (t - \[Phi][w, \[Zeta]]/(2 Pi))]
us[t_] := Sin[2 Pi t]
Manipulate[
 GraphicsRow[{GraphicsColumn[{Plot[Rd[w, \[Zeta]], {w, 0, 3},
      AxesOrigin -> {1, 1}, PlotRange -> {{0, 3}, {0, 5}},
      AxesLabel -> {"\!\(\*FractionBox[\"\[Omega]\", SubscriptBox[\"\
\[Omega]\", \"0\"]]\)", "\!\(\*SubscriptBox[\"R\", \"d\"]\)"},
      Epilog -> {PointSize[Large], Red, Point[{w, Rd[w, \[Zeta]]}]},
      Ticks -> {{0, 1, 2, 3}, {0, 1, 2, 3, 4, 5}}],
     Plot[\[Phi][w, \[Zeta]], {w, 0, 3}, AxesOrigin -> {1, Pi/2},
      PlotRange -> {{0, 3}, {0, Pi}},
      AxesLabel -> {"\!\(\*FractionBox[\"\[Omega]\", SubscriptBox[\"\
\[Omega]\", \"0\"]]\)", "\[Phi]"},
      Epilog -> {PointSize[Large], Red,
        Point[{w, \[Phi][w, \[Zeta]]}]},
      Ticks -> {{0, 1, 2, 3}, {0, Pi/2, Pi}}]}, Frame -> All],
   Plot[{ud[w, \[Zeta], t], us[t]}, {t, 0, 2},
    PlotStyle -> {Thick, Dashed},
    AxesLabel -> {"t/T",
      "\!\(\*SubscriptBox[\"u\", \"d\"]\)/\!\(\*SubscriptBox[\"u\", \
\"st\"]\)"}]}, Frame -> All], {{w, 0.5, "Frequency ratio"}, 0,
  3}, {{\[Zeta], 0.2, "Damping ratio"}, 0, 1}]

Special cases include

Long period excitation, i.e., $\omega\ll\omega_0$ , gives a pseudo-static response. In this case, the system “waits” until it “feels” the excitation completely. $R_d$ is greater but very close to $1$ , and the displacement is essentially in phase with excitation force, in other words, dynamic effect is near to none.
Long period/low frequency loading response
Short period excitation gives very small $R_d$ , though the phase lag is $\pi$ . Here the system barely reacts when the load is reversed, thus leads to small displacement.
Short period/high frequency loading response
Resonant period, i.e., $\omega\approx\omega_0$ , leads to $\phi\approx\pi/2$ . Now $R_d$ is very sensitive to damping change, namely, the response is controlled by the damping: a small change of damping ratio $\zeta$ leads to great reaction of the structure. When $\omega=\omega_0$ , we have $R_d=1/(2 \zeta)$ .
Resonant frequency: small damping

Resonant frequency: medium damping

Resonant frequency: large damping